PC Answers 1998 January/PC Answers Issue 49 Cover CD January 1998.iso/Apps/Director/DATA.Z/Animation Wizard.dir/00013_ScoreMgr.ls

Text File | 1997-05-10 | 11.5 KB | 371 lines

property iUsersScoreSelection, iGeneratedScoreSelection, ichStart, ichEnd, iFrameStart, iFrameEnd, iStageWidth, iStageHeight, iStageRight, iStageBottom, iChannelAvailList, ichReselect, iLocReselect, ikChStart, ikChEnd, ikFrameStart, ikFrameEnd, iLastFrame, iNeedClean

on birth me
  tell the stage
    set iStageRight to the stageRight
    set iStageBottom to the stageBottom
    set iStageWidth to iStageRight - the stageLeft
    set iStageHeight to iStageBottom - the stageTop
  end tell
  set ikChStart to 1
  set ikChEnd to 2
  set ikFrameStart to 3
  set ikFrameEnd to 4
  set iChannelAvailList to []
  set iGeneratedScoreSelection to []
  set ichReselect to 18
  return me
end

on mGetStageWidth me
  return iStageWidth
end

on mGetStageHeight me
  return iStageHeight
end

on mGetStageRight me
  return iStageRight
end

on mGetStageBottom me
  return iStageBottom
end

on mInit me, nFramesNeeded, nChannelsNeeded
  global gDevelopmentFlag
  if nFramesNeeded > 32000 then
    alert("The combination of text and settings you have chosen would generate an " & "animation of more than 32000 frames.  Please simplify your selections and try again.")
    return 0
  end if
  tell the stage
    set iUsersScoreSelection to the scoreSelection
    set iLastFrame to the lastFrame
    set iStageRight to the stageRight
    set iStageBottom to the stageBottom
    set iStageWidth to iStageRight - the stageLeft
    set iStageHeight to iStageBottom - the stageTop
  end tell
  if iUsersScoreSelection = [] then
    alert("Please select a range of cells or frames in the score and try again.")
    return 0
  end if
  if gDevelopmentFlag then
    mForceSelection(me)
  end if
  set iLocReselect to the loc of sprite ichReselect
  puppetSprite(ichReselect, 1)
  set firstScoreSelectionList to getAt(iUsersScoreSelection, 1)
  set ichStart to getAt(firstScoreSelectionList, ikChStart)
  set ichEnd to getAt(firstScoreSelectionList, ikChEnd)
  set iFrameStart to getAt(firstScoreSelectionList, ikFrameStart)
  set iFrameEnd to getAt(firstScoreSelectionList, ikFrameEnd)
  set theGeneratedFrameEnd to iFrameStart + nFramesNeeded - 1
  set theEnd to max(theGeneratedFrameEnd, iFrameEnd)
  if theEnd >= iLastFrame then
    set iNeedClean to 1
    tell the stage
      beginRecording()
      go(theEnd + 5)
      set the frameTempo to 5
      endRecording()
    end tell
  else
    set iNeedClean to 0
  end if
  set iChannelAvailList to []
  if (ichStart = -5) and (ichEnd = 48) then
    repeat with ch = 1 to 48
      add(iChannelAvailList, ch)
    end repeat
    tell the stage
      beginRecording()
      if iFrameEnd >= iFrameStart then
        go(iFrameStart)
        repeat with theFrameNum = iFrameStart to iFrameEnd
          set the frameLabel to 0
          deleteFrame()
        end repeat
      end if
      tell the stage
        if iFrameStart = 1 then
          go(1)
        else
          go(iFrameStart - 1)
        end if
        repeat with i = 1 to nFramesNeeded
          insertFrame()
        end repeat
        if iFrameStart = 1 then
          go(1)
        else
          go(iFrameStart - 1)
        end if
      end tell
      set theEnd to max(theGeneratedFrameEnd, iFrameEnd)
      if theEnd >= iLastFrame then
        set iNeedClean to 1
        go(theEnd + 5)
        set the frameTempo to 5
      else
        set iNeedClean to 0
      end if
      endRecording()
    end tell
    set iGeneratedScoreSelection to [[-5, 48, iFrameStart, theGeneratedFrameEnd]]
  else
    set iGeneratedScoreSelection to []
    set nItems to count(iUsersScoreSelection)
    repeat with thisSelection = 1 to nItems
      set thisScoreSelectionList to getAt(iUsersScoreSelection, thisSelection)
      set thisChStart to getAt(thisScoreSelectionList, ikChStart)
      if thisChStart <= 0 then
        alert("Please make your score selection in channels 1 through 48")
        mClean(me)
        return 0
      end if
      set thisChEnd to getAt(thisScoreSelectionList, ikChEnd)
      set thisScoreSelection to [thisChStart, thisChEnd, iFrameStart, theGeneratedFrameEnd]
      addAt(iGeneratedScoreSelection, thisScoreSelection)
      repeat with thisCh = thisChStart to thisChEnd
        add(iChannelAvailList, thisCh)
      end repeat
    end repeat
    set nChannelsAvail to count(iChannelAvailList)
    if nChannelsNeeded > nChannelsAvail then
      alert("Your animation requires" && nChannelsNeeded && "channels, " & "but you have only selected" && nChannelsAvail && "channels.  " & "Please select more and try again.")
      mClean(me)
      return 0
    end if
    set nFramesSelected to iFrameEnd - iFrameStart + 1
    if nFramesSelected < nFramesNeeded then
      set nFramesToAdd to nFramesNeeded - nFramesSelected
      tell the stage
        go(iFrameEnd)
        beginRecording()
        repeat with i = 1 to nFramesToAdd
          duplicateFrame()
          set the frameTempo to 0
        end repeat
        endRecording()
        go(iFrameStart)
      end tell
    end if
  end if
  tell the stage
    beginRecording()
    go(iFrameStart)
    repeat with thisFrame = iFrameStart to iFrameEnd
      repeat with chIndex = 1 to nChannelsAvail
        set thisCh to getAt(iChannelAvailList, chIndex)
        if the castNum of sprite thisCh <> 0 then
          set the type of sprite thisCh to 0
        end if
      end repeat
      set the frameTempo to 0
      updateFrame()
    end repeat
    endRecording()
  end tell
  updateStage()
  return 1
end

on mShowReselect me
  set the scoreSelection to iUsersScoreSelection
  set the loc of sprite ichReselect to iLocReselect
  set the castNum of sprite ichReselect to the number of member "ReselectButton"
  updateStage()
end

on mForceSelection me
  set nItems to count(iUsersScoreSelection)
  repeat with thisSelectionNum = 1 to nItems
    set thisScoreSelectionList to getAt(iUsersScoreSelection, thisSelectionNum)
    set thisStart to getAt(thisScoreSelectionList, ikFrameStart)
    set thisEnd to getAt(thisScoreSelectionList, ikFrameEnd)
    if (thisStart < 101) or (thisEnd < 101) then
      setAt(thisScoreSelectionList, ikFrameStart, 101)
      setAt(thisScoreSelectionList, ikFrameEnd, 125)
      setAt(iUsersScoreSelection, thisSelectionNum, thisScoreSelectionList)
    end if
  end repeat
end

on mReselect me
  if iGeneratedScoreSelection = [] then
    alert("Internal error, mReselect - there is nothing to reselect.")
    return
  end if
  tell the stage
    set the scoreSelection to iGeneratedScoreSelection
  end tell
end

on mGetGeneratedScoreSelection me
  return iGeneratedScoreSelection
end

on mGetStartFrame me
  return iFrameStart
end

on mGetNextSelectedChannel me
  if iChannelAvailList = [] then
    alert("Internal error, mGetNextSelectedChannel is out of available channels")
    return -99
  end if
  set theCh to getAt(iChannelAvailList, 1)
  deleteAt(iChannelAvailList, 1)
  return theCh
end

on mWriteSprite me, f, ch, cm, theForeColor, theBackColor, x, y, w, h
  global gkTransparentInk
  tell the stage
    go(f)
    beginRecording()
    set the castNum of sprite ch to cm
    set the foreColor of sprite ch to theForeColor
    set the backColor of sprite ch to theBackColor
    set the locH of sprite ch to x
    set the locV of sprite ch to y
    set the ink of sprite ch to gkTransparentInk
    set the tweened of sprite(ch) to 1
    if w <> 0 then
      set the width of sprite ch to w
    end if
    if h <> 0 then
      set the height of sprite ch to h
    end if
    updateFrame()
    endRecording()
  end tell
end

on mWriteFrameControl me, theFrame, theControl, theValue
  if theControl = #transition then
    copyToClipBoard(member the number of member theValue)
    set castNumTransTarget to mFindFreeCastRun(goCastMgr, 1, 1)
  end if
  tell the stage
    go(theFrame)
    beginRecording()
    case theControl of
      #label:
        set the frameLabel to theValue
      #tempo:
        set the frameTempo to theValue
      #transition:
        pasteClipBoardInto(member castNumTransTarget)
        set the name of member castNumTransTarget to "Transition" && string(the ticks)
        set the frameTransition to castNumTransTarget
      #Sound1:
        set the frameSound1 to theValue
      #Sound2:
        set the frameSound2 to theValue
      otherwise:
        alert("Bad control value passed to mWriteFrameControl" & theControl)
    end case
    updateFrame()
    endRecording()
  end tell
end

on mWriteFrameLabel me, theFrame, theLabel
  mWriteFrameControl(me, theFrame, #label, theLabel)
end

on mWriteFrameDelay me, theFrame, nSeconds
  mWriteFrameControl(me, theFrame, #tempo, -nSeconds)
end

on mWriteFrameTempo me, theFrame, theTempo
  mWriteFrameControl(me, theFrame, #tempo, theTempo)
end

on mWriteFrameTransition me, theFrame, theTransition
  mWriteFrameControl(me, theFrame, #transition, theTransition)
end

on mWriteFrameSound1 me, theFrame, theSound1
  mWriteFrameControl(me, theFrame, #Sound1, theSound1)
end

on mWriteFrameSound2 me, theFrame, theSound2
  mWriteFrameControl(me, theFrame, #Sound2, theSound2)
end

on mWriteFrame me, frameList
  global gkTransparentInk
  tell the stage
    beginRecording()
    repeat with theFrameNum = 1 to count(frameList)
      set theFrameStuff to getAt(frameList, theFrameNum)
      go(getAt(theFrameStuff, 1))
      repeat with theChannel = 2 to count(theFrameStuff)
        set theChannelList to getAt(theFrameStuff, theChannel)
        set theChannelType to getAt(theChannelList, 1)
        case theChannelType of
          #label:
            set the frameLabel to getAt(theChannelList, 2)
          #tempo:
            set the frameTempo to getAt(theChannelList, 2)
          #palette:
            set the framePalette to getAt(theChannelList, 2)
          #transition:
            set theTransition to getAt(theChannelList, 2)
            set transitionMember to new(#transition)
            if theTransition = "wipe down" then
              set the transitionType of transitionMember to 3
              set the chunkSize of transitionMember to 2
            else
              if theTransition = "dissolve, pixels fast" then
                set the transitionType of transitionMember to 23
                set the chunkSize of transitionMember to 1
              end if
            end if
            set the duration of transitionMember to 2000
            set the frameTransition to transitionMember
          #Sound1:
            set the frameSound1 to getAt(theChannelList, 2)
          #Sound2:
            set the frameSound2 to getAt(theChannelList, 2)
          #sprite:
            set theSpriteNum to getAt(theChannelList, 2)
            set the castNum of sprite theSpriteNum to getAt(theChannelList, 3)
            set the foreColor of sprite theSpriteNum to getAt(theChannelList, 4)
            set the backColor of sprite theSpriteNum to getAt(theChannelList, 5)
            set the locH of sprite theSpriteNum to getAt(theChannelList, 6)
            set the locV of sprite theSpriteNum to getAt(theChannelList, 7)
            set the ink of sprite theSpriteNum to gkTransparentInk
            set the tweened of sprite(theSpriteNum) to 1
            set w to getAt(theChannelList, 8)
            set h to getAt(theChannelList, 9)
            if w <> 0 then
              set the width of sprite theSpriteNum to w
            end if
            if h <> 0 then
              set the height of sprite theSpriteNum to h
            end if
        end case
      end repeat
      updateFrame()
    end repeat
    endRecording()
  end tell
end

on mClean me
  if iNeedClean = 1 then
    tell the stage
      set iLastFrame to the lastFrame
      beginRecording()
      go(iLastFrame)
      set the frameTempo to 0
      endRecording()
    end tell
  end if
end